Маркировка_ЗаполнитьКоды

Добавлено в версии 4.52.

Синтаксис:

Маркировка_ЗаполнитьКоды

Описание:

Заполняет данные маркировки в контенте электронного документа с помощью подсистем «ИС МП» или «Контур.Маркировка».

Выбор подсистемы «ИС МП» или «Контур.Маркировка» определяется настройкой «Использовать сервис Контур.Маркировка».

Работает с УПД в формате 970@. Работает с УКД в формате 29@ с версии 4.70.

Входные параметры:

  • Контент (тип Структура, ОбъектXDTO) — контент электронного документа.

  • ОписаниеТипаКонтента (тип Структура, ФиксированнаяСтруктура) — описание типа электронного документа. Передаётся в виде структуры, соответствующей контракту ТипЭлектронногоДокумента или ВидЭлектронногоДокумента.

  • ДопПараметры (тип Структура, ФиксированнаяСтруктура) — дополнительные параметры для работы с УКД. Смотрите метод Маркировка_ПараметрыЗаполнения. Добавлено в версии 4.70.

Дополнительная информация

Строки товарной части контента utd970 и ucd29 должны содержать заполненную служебную информацию. Обязательны для заполнения реквизиты: «документ-основание отгрузки» и «номенклатура». При наличии определенных условий заполняются реквизиты: «характеристика» и «серия».

Условия заполнения:

  • Если в конфигурации есть характеристики и серии и они заполнены, тогда заполните поля «характеристика» и «серия» соответствующими значениями.

  • Если в конфигурации есть характеристики и серии и они не заполнены, тогда заполните поля «характеристика» и «серия» пустыми ссылками на метаданные характеристики и серии.

  • Если в конфигурации нет характеристик и серий, тогда поля «характеристика» и «серия» оставьте не заполненными.

Поддерживаемые системы хранения:

  • Система хранения Диадок.

  • Система хранения 1С.

Примеры заполнения кодов маркировки

УПД 970
Функция ПодготовитьЭлектронныйДокумент(ПараметрыСобытия)

    ВидДокументаРазвернутый = ПараметрыСобытия.ВидДокументаРазвернутый;
    Content = ПараметрыСобытия.Результат.Content;

    // ДокументСсылка.СчетФактураВыданный
    Документ1С = ПараметрыСобытия.Результат.Документ1С;

    // ДокументСсылка.РеализацияТоваровУслуг
    ДокументОснование = ДокументыОснование(Документ1С);

    ДанныеТоваров1С = ДанныеТоваров1С(ДокументОснование);

    Для Каждого ТекСтрока Из ДанныеТоваров1С Цикл

        Item = ОсновнойМодуль.НовыйЭлементСпискаXDTO(Content.Table.Items);

        УстановитьЗначениеXDTO(Item.СлужебнаяИнформация, "ДокументОтгрузки", ЗначениеВСтрокуВнутр(ДокументОснование));
        УстановитьЗначениеXDTO(Item.СлужебнаяИнформация, "Номенклатура", ЗначениеВСтрокуВнутр(ТекСтрока.Номенклатура));

    КонецЦикла;

    ОсновнойМодуль.Маркировка_ЗаполнитьКоды(Content, ВидДокументаРазвернутый);

КонецФункции
УКД 29
Функция ПодготовитьЭлектронныйДокумент(ПараметрыСобытия)

    ВидДокументаРазвернутый = ПараметрыСобытия.ВидДокументаРазвернутый;
    Content = ПараметрыСобытия.Результат.Content;

    // ДокументСсылка.СчетФактураВыданный
    Документ1С = ПараметрыСобытия.Результат.Документ1С;

    // ДокументСсылка.КорректировкаРеализации
    ДокументОснование = ДокументыОснование(Документ1С);

    // ДокументСсылка.РеализацияТоваровУслуг
    ИсправляемыйДокумент = ИсправляемыйДокументРеализации(ДокументОснование);

    ДанныеТоваров1С = ДанныеТоваров1С(ДокументОснование);

    Для Каждого ТекСтрока Из ДанныеТоваров1С Цикл

        Item = ОсновнойМодуль.НовыйЭлементСпискаXDTO(Content.InvoiceCorrectionTable.Items);

        УстановитьЗначениеXDTO(Item.СлужебнаяИнформация, "ДокументОтгрузки", ЗначениеВСтрокуВнутр(ДокументОснование));
        УстановитьЗначениеXDTO(Item.СлужебнаяИнформация, "Номенклатура", ЗначениеВСтрокуВнутр(ТекСтрока.Номенклатура));

    КонецЦикла;

    ДопПараметры = ОсновнойМодуль.Маркировка_ПараметрыЗаполнения();

    ДопПараметры.ИсправляемыеДокументы.Добавить(ИсправляемыйДокумент);

    ОсновнойМодуль.Маркировка_ЗаполнитьКоды(Content, ВидДокументаРазвернутый, ДопПараметры);

КонецФункции

Особенности и ограничения

Особенности при работе с «Контур.Маркировка»

Рекомендуется применение для версии модуля «Контур.Маркировка» 3.10.1 и выше. Допускается использование на версиях не ниже 1.10. Важно соблюдение технических требований модуля «Контур.Маркировка» для соответствующей версии.

Подробнее про описание технических требований

Особенности при работе с «ИС МП»

Применение в совместимых с модулем конфигурациях поддерживаемых версий, содержащих типовую подсистему «ИС МП».

Не гарантируется работа на совместимых типовых конфигурациях, версии которых ниже поддерживаемых.

Исключение для использования подсистемы «ИС МП»: версии поддерживаемых конфигураций без типовой подсистемы «ИС МП» (например, Автосалон+Автосервис+Автозапчасти 5.1/6.0) или версии, использующие только локальный модуль «Честный знак» (например, Автосалон+Автосервис+Автозапчасти 6.1).

Подробнее про описание поддерживаемых версий

Ограничения

Не гарантируется работа метода в следующих случаях:

  • Версия модуля «Диадок» или модуля «Контур.Маркировка» ниже рекомендуемых.

  • Версия совместимой с модулем «Диадок» конфигурации ниже поддерживаемой.

  • Конфигурация доработана в части учета маркируемой продукции. Например, в БП 3.0 добавлены справочники характеристики и серий номенклатуры.

  • Подсистема «ИС МП» добавлена в конфигурацию самостоятельно.

  • Модуль «Контур.Маркировка» доработан самостоятельно.

Связанные методы: