ЭДО_ОтменаФиксации_ОтправитьКвитанцию

Добавлено в версии 5.55.

Синтаксис:

ЭДО_ОтменаФиксации_ОтправитьКвитанцию

Описание:

Отправляет квитанцию об отмене фиксации кодов маркировки. Перед вызовом метода следует указать ящик — ЭДО_УстановитьТекущийЯщик.

Входные параметры:

• ЭлектронныйДокумент (тип СправочникСсылка.Диадок_Документы) — электронный документ, по которому требуется сформировать квитанцию об отмене фиксации кодов маркировки.

• ОтменаФиксации (тип ДвоичныеДанные) — файл квитанции об отмене фиксации.

• Подпись (тип ДвоичныеДанные) — файл подписи к квитанции об отмене фиксации.

Пример:

Функция ОбработатьОтменыФиксации(СписокЯщиков)

    Запрос = Новый Запрос;

    Запрос.Текст = ТекстЗапроса_ДокументыДляОтменыФиксации();

    Запрос.УстановитьПараметр("СписокЯщиков", СписокЯщиков);

    ВыборкаОрганизаций = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

    Пока ВыборкаОрганизаций.Следующий() Цикл

        BoxId = ВыборкаОрганизаций.BoxId;

        // Выбор текущего ящика
        ОсновнойМодуль.ЭДО_УстановитьТекущийЯщик(BoxId);

        // Заполнение МЧД
        Контракт_МЧД = ОсновнойМодуль.Контракт_МЧД();

        Контракт_МЧД.Идентификатор      = ВыборкаОрганизаций.ИдентификаторМЧД;
        Контракт_МЧД.ДоверительИНН      = ВыборкаОрганизаций.ИННОрганизации;
        Контракт_МЧД.ПредставительИНН   = ВыборкаОрганизаций.ИННПодписанта;

        ОсновнойМодуль.ЗаполнитьДанныеМЧД(BoxId, Контракт_МЧД);

        Выборка = ВыборкаОрганизаций.Выбрать();

        Пока Выборка.Следующий() Цикл

            ДокументДД              = Выборка.ДокументДД;
            ОтпечатокСертификата    = Выборка.ОтпечатокСертификата;

            // Формирование файла квитанции
            Квитанция = ОсновнойМодуль.ЭДО_ОтменаФиксации_СформироватьКвитанцию(ДокументДД);

            // Подписание квитанции
            РезультатПодписания = ОсновнойМодуль.ПодписатьДанныеНаСервере(Квитанция, ОтпечатокСертификата);

            // Отправка квитанции в Диадок
            Если РезультатПодписания.Успешно Тогда

                Подпись = РезультатПодписания.ДвоичныеДанныеПодписи;

                Попытка
                    ОсновнойМодуль.ЭДО_ОтменаФиксации_ОтправитьКвитанцию(ДокументДД, Квитанция, Подпись);
                Исключение
                    ТекстОшибки = ОписаниеОшибки();
                    ЗаписатьВЖурналРегистрацииОшибку("Диадок.ОшибкаОтправкиОтменыФиксации", ДокументДД, ТекстОшибки);
                КонецПопытки;

            КонецЕсли;

        КонецЦикла;

        // Очистка данных МЧД
        ОсновнойМодуль.ОчиститьДанныеМЧД();

    КонецЦикла;

КонецФункции