ЭДО_СписокСотрудниковДиадока

Синтаксис:

ЭДО_СписокСотрудниковДиадока

Описание:

Получает список всех сотрудников организации Диадока.

Примечание

Вызов метода доступен только администраторам организации.

Входные параметры:

• BoxId (тип Строка) — адрес или идентификатор ящика Диадока.

Возвращает:

ФиксированныйМассив с элементами ФиксированнаяСтруктура — список сотрудников организации Диадока.

Элементы структуры:

• ИдентификаторПользователя (тип Строка) — идентификатор пользователя в сервисе Диадок.

• Зарегистрирован (тип Булево) — признак регистрации учетной записи.

• Логин (тип Строка) — логин пользователя.

• Фамилия (тип Строка) — фамилия сотрудника.

• Имя (тип Строка) — имя сотрудника.

• Отчество (тип Строка) — отчество сотрудника.

• Должность (тип Строка) — должность сотрудника.

• ИдентификаторПодразделения (тип Строка) — идентификатор подразделения сотрудника.

• Администратор (тип Булево) — признак администратора организации.

• УровеньДоступаКДокументам (тип Строка) — уровень доступа к документам Диадока. Смотрите таблицу Уровни доступа сотрудника к документам организации.

• ИдентификаторыДоступныхПодразделений (тип ФиксированныйМассив) — идентификаторы подразделений, к документам которых есть доступ при уровне SelectedDepartments.

• Действия (тип ФиксированныйМассив) — права на действия. Элемент массива — структура.

  Элементы структуры:

  • Наименование (тип Строка) — идентификатор действия Диадока. Смотрите таблицу Доступность действия.

  • Разрешено (тип Булево) — признак доступности действия.

Поддерживаемые системы хранения:

• Система хранения Диадок.

• Система хранения 1С.

Пример получения списка сотрудников для согласования документов

Функция СписокСотрудниковДляСогласованияДокументов(BoxId)

    СписокСотрудников = ОсновнойМодуль.ЭДО_СписокСотрудниковДиадока(BoxId);
    Результат = Новый Массив;

    Для Каждого ДанныеСотрудника Из СписокСотрудников Цикл

        Если Не ДанныеСотрудника.Зарегистрирован Тогда
            Продолжить;
        КонецЕсли;

        МожетСогласовыватьДокументы = СотрудникуРазрешеноСогласовыватьДокументы(ДанныеСотрудника.Действия);

        Если МожетСогласовыватьДокументы Тогда

            Согласующий = Новый Структура;
            Согласующий.Вставить("Фамилия", ДанныеСотрудника.Фамилия);
            Согласующий.Вставить("Имя", ДанныеСотрудника.Имя);
            Согласующий.Вставить("Отчество", ДанныеСотрудника.Отчество);
            Согласующий.Вставить("Должность", ДанныеСотрудника.Должность);

            Результат.Добавить(Согласующий);

        КонецЕсли;

    КонецЦикла;

    Возврат Результат;

КонецФункции

Функция СотрудникуРазрешеноСогласовыватьДокументы(ДоступныеДействия)

    Результат = Ложь;

    Для Каждого Действие Из ДоступныеДействия Цикл

        Если Действие.Наименование = "AddResolutions" Тогда
            Результат = Действие.Разрешено;
            Прервать;
        КонецЕсли;

    КонецЦикла;

    Возврат Результат;

КонецФункции

Дополнительная информация

Уровни доступа сотрудника к документам организации:

Значение	Описание
UnknownDocumentAccessLevel	Неизвестное значение
DepartmentOnly	Пользователю доступны только документы из подразделения, в котором он состоит
DepartmentAndSubdepartments	Пользователю доступны документы из подразделения, в котором он состоит, и из всех его дочерних подразделений
AllDocuments	Пользователю доступны все документы организации
SelectedDepartments	Пользователю доступны документы из нескольких подразделений

Доступность действия:

Значение	Описание
CreateDocuments	Создавать и редактировать документы и черновики
DeleteRestoreDocuments	Удалять документы и черновики, восстанавливать документы
SignDocuments	Подписывать документы
AddResolutions	Согласовывать документы
RequestResolutions	Передавать на подпись и согласование
ManageCounteragents	Видеть списки контрагентов и работать с ними
AttachUniversalMessages	Отправлять универсальные сообщения
UseGoskey	Использовать для подписания документов сертификат «Госключ» физического лица